ONOFF EXAMPLES
Keywords: pako

Next: OTFMAP Up: ONOFF Previous: ONOFF /TSUBSCAN Contents Index

###
ONOFF EXAMPLES

        !
        ! Id: demo-onoff.pako
        !     ONOFF SWTOTAL EXAMPLE,v 1.1.1 2009-05-05 Hans Ungerechts
        !     "POSITION SWITCHING"
        !
        @ demo-rx-spectrometers                     !  demo setup of receivers
        !                                           !  and spectrometers
        !                                           !  REPLACE WITH YOUR SETUP!
        !
        SET ANGLE arcsec                            !
        !
        SWTOTAL                                   - !  select total power
          /TPHASE        0.5                        !  time per phase (data sample)
        !
        CALIBRATE                                 - !
          /AMBIENT                                - !  ambient load
          /COLD                                   - !  cold    load
          /SKY       -600.0   0.0                 - !  sky at offsets -600.0 0.0
          /SYSTEM       projection                - !  system for SKY offsets
          /TCALIBRATE   5.0                         !  time per calibration subscan
        !
        PAUSE "CALIBRATE OK to start? [c/q]"        !  a chance to check
        !
        START                                       !  start
        !
        ONOFF           40.0   -30.0              - !  offsets of on position
          /NSUBSCANS    12                        - !  number of subscans
          /REFERENCE  -600.0     0.0   projection - !  offsets of off-source referen
          /SYSTEM       projection                - !  system for offsets
          /SYMMETRIC                              - !  "symmetric" subscan sequence
          /TSUBSCAN     30                          !  time per subscan
        !
        PAUSE "ONOFF SWTOTAL OK to start? [c/q]"    !  a chance to check
        !
        START                                       !  start
        !
        !! Comments:
        !! we assume here that the source already has been selected,
        !! see: demo-source

        !
        ! Id: demo-onoff-swwobbler.pako
        !     ONOFF SWWOBBLER EXAMPLE,v 1.1.6 2011-07-31 Hans Ungerechts
        !     "WOBBLER SWITCHING"
        !
        @ demo-rx-spectrometers                     !  demo setup of receivers
        !                                           !  and spectrometers
        !                                           !  REPLACE WITH YOUR SETUP!
        !
        SET ANGLE arcsec                            !
        !
        !                                           !  select wobbler switching
        SWWOBBLER     -120.0   120.0              - !  wobbler -/+ 120 arc sec
          /TPHASE        1.0                        !  1 seconds per phase
        !
        CALIBRATE                                 - !
          /AMBIENT                                - !  ambient load
          /COLD                                   - !  cold    load
          /SKY       -600.0   0.0                 - !  sky at offsets -600.0 0.0
          /SYSTEM       projection                - !  system for SKY offsets
          /TCALIBRATE   5.0                         !  time per calibration subscan
        !
        PAUSE "CALIBRATE OK to start? [c/q]"        !  a chance to check
        !
        START                                       !  start
        !
        !!                                          !  OPTIONAL:
        !! OFFSETS  20 30                         - !  mapping offsets in
        !!  /SYSTEM projection                      !  system projection
        !
        ONOFF   /SWWOBBLER                        - !  ONOFF for Wobbler switching
          /NSUBSCANS    12                        - !  number of subscans
          /SYMMETRIC                              - !  "symmetric" subscan sequence
          /TSUBSCAN     30                          !  time per subscan
        !
        PAUSE "ONOFF SWWOBBLER OK to start? [c/q]"  !  a chance to check
        !
        START                                       !  start
        !
        !! Comments:
        !! we assume here that the source already has been selected,
        !! see: demo-source
        !!
        !! IMPORTANT NOTE: ONOFF with SWWOBBLER (wobbler switching on-off)
        !! requires that the subscans are offset relative to the source
        !! in the trueHorizon system by -1 * the  Wobbler elongations (offsets).
        !! With the commands above, paKo recognizes this and automatically
        !! sets the correct values.
        !! In this case, OFFSETS can be used to set additional mapping
        !! offsets in the  "projection" of the astronomical coordinate
        !! system.  These mapping offsets in the projection apply
        !! to all ONOFF subscans.